Windows配置Vlmcsd自启动搭建KMS服务器，提供激活服务教程

通过Hyper-v创建虚拟机，在控制面板\程序\启用或关闭Windows功能添加Hyper-v

桥接网络直通方法设置如下：
1.打开【Hyper-V管理器】，右键【虚拟交换机管理器】，【新建虚拟网络交换机】【外部】【创建虚拟交换机】
2.名称【桥接，可自定义】，外部网络【选择网卡】，允许管理操作系统共享此网络适配器【勾选√】
3.选择创建的【虚拟机，例如win10】右键【设置】【网络适配器】【虚拟交换机】【桥接】确定即可
针对导入的虚拟机，前提也是配置好桥接网络直通再导入。
vlmcsd从github下载https://github.com/Wind4/vlmcsd/releases下载最新版，以2020-03-28 (svn1113)版本为例进行配置实现自启动。
下载成功后，解压出来binaries.tar.gz\binaries\Windows\intel\vlmcsd-Windows-x64，将vlmcsd-Windows-x64放到c盘kms目录下vlmcsd-Windows-x64
防火墙开放1688端口规则，以管理员权限运行cmd为例：

#防火墙开放1688端口规则
netsh advfirewall firewall add rule name=kms1688 dir=in action=allow protocol=TCP localport=1688

安装vlmcsd服务，以管理员权限运行cmd为例：

#cmd管理员模式运行命令
cd c:/
cd kms
#创建kms服务
vlmcsd-Windows-x64  -s
#以下为运行后的输出结果：提示如下说明创建服务成功
#Service installed successfully
#启动vlmcsd服务
sc start vlmcsd
#以下为运行后的输出结果：提示如下说明启动服务成功
SERVICE_NAME: vlmcsd
        TYPE               : 10  WIN32_OWN_PROCESS
        STATE              : 2  START_PENDING
                                (NOT_STOPPABLE, NOT_PAUSABLE, IGNORES_SHUTDOWN)
        WIN32_EXIT_CODE    : 0  (0x0)
        SERVICE_EXIT_CODE  : 0  (0x0)
        CHECKPOINT         : 0x0
        WAIT_HINT          : 0x7d0
        PID                : 2280
        FLAGS              :
#也可以这样启动vlmcsd服务，在任务管理器查找启动
【任务栏】 右键→【任务管理器】→【服务】 搜索【vlmcsd】选择【 启动】→状态 【正在运行】，说明服务已经启动成功。

防火墙关闭1688端口规则，以管理员权限运行cmd为例：

#关闭1688端口规则
netsh advfirewall firewall delete rule name=kms1688

#以下为运行后的输出结果：
已删除 1 规则。
确定。
https://blog.csdn.net/weixin_39372311/article/details/144017981

如何卸载创建的vlmcsd服务，以管理员权限运行cmd为例

sc queryex state= all  #列出全部服务
sc stop vlmcsd         #停止vlmcsd服务
sc delete vlmcsd       #删除vlmcsd服务

#以下为运行后的输出结果：
C:\Windows\System32>sc stop vlmcsd
SERVICE_NAME: vlmcsd
        TYPE               : 10  WIN32_OWN_PROCESS
        STATE              : 3  STOP_PENDING
                                (STOPPABLE, NOT_PAUSABLE, IGNORES_SHUTDOWN)
        WIN32_EXIT_CODE    : 0  (0x0)
        SERVICE_EXIT_CODE  : 0  (0x0)
        CHECKPOINT         : 0x1
        WAIT_HINT          : 0x0
C:\Windows\System32>sc delete vlmcsd
[SC] DeleteService 成功

Windows 11 24H2企业版激活方法

slmgr.vbs -upk
slmgr.vbs -ipk NPPR9-FWDCX-D2C8J-H872K-2YT43
slmgr.vbs -skms IP
slmgr.vbs -dlv
slmgr.vbs /ato

Windows 10 LTSC 2019/2021/2024企业版激活方法

slmgr.vbs -upk
slmgr.vbs -ipk M7XTQ-FN8P6-TTKYV-9D4CC-J462D
slmgr.vbs -skms IP
slmgr.vbs -dlv
slmgr.vbs /ato

Windows Server 2025 Datacenter激活方法

slmgr.vbs -upk
slmgr.vbs -ipk D764K-2NDRG-47T6Q-P8T8W-YP6DF
slmgr.vbs -skms IP
slmgr.vbs -dlv
slmgr.vbs /ato

以cn_windows_server_2016_updated_feb_2018_x64_dvd_11636703.iso为例，cmd管理员运行

slmgr /upk
slmgr /ipk WC2BQ-8NRM3-FDDYY-2BFGV-KHKQY
slmgr /skms 192.168.111.3
slmgr /ato

激活office2010和2016

以SW_DVD5_Office_Professional_Plus_2010w_SP1_64Bit_ChnSimp_CORE_MLF_X17-76742为例，cmd管理员运行，不是PowerShell

cd C:\Program Files\Microsoft Office\Office14
cscript ospp.vbs /sethst:192.168.111.3
cscript ospp.vbs /act

以SW_DVD5_Office_Professional_Plus_2016_64Bit_ChnSimp_MLF_X20-42426为例，cmd管理员运行，不是PowerShell

cd C:\Program Files\Microsoft Office\Office16
cscript ospp.vbs /sethst:192.168.111.3
cscript ospp.vbs /act

180天到期再次激活

Windows 10 enterprise、Windows 10 ltsc 2019和windows server 2016，cmd管理员运行，不是PowerShell，直接执行命令KMS服务器地址和slmgr /ato即可再次延期。

slmgr /skms 192.168.111.3
slmgr /ato

以下为一键脚本，另存为bat脚本，编码 ANSI 保存

@echo off
setlocal enabledelayedexpansion
title Windows 激活与版本检测工具 v6.1

:: --- 自动获取管理员权限 ---
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' ( goto UACPrompt ) else ( goto gotAdmin )
:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
    "%temp%\getadmin.vbs"
    exit /B
:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%~dp0"

echo ========================================
echo        系统版本检测 (PowerShell)
echo ========================================

:: --- 提取系统名称 (Caption) ---
for /f "usebackq tokens=*" %%a in (`powershell -NoProfile -Command "(Get-CimInstance Win32_OperatingSystem).Caption"`) do set "os_name=%%a"

:: --- 提取版本型号 (如 24H2, 23H2) ---
for /f "usebackq tokens=*" %%a in (`powershell -NoProfile -Command "(Get-ItemProperty 'HKLM:\SOFTWARE\Microsoft\Windows NT\CurrentVersion').DisplayVersion"`) do set "os_ver=%%a"

echo [检测] 系统名称: %os_name%
echo [检测] 版本型号: %os_ver%
echo ----------------------------------------

set "active_key="
set "os_label="

:: --- 逻辑匹配开始 ---

:: 1. 匹配 LTSC
echo %os_name% | findstr /i "LTSC" >nul
if !errorlevel! equ 0 (
    set "active_key=M7XTQ-FN8P6-TTKYV-9D4CC-J462D"
    echo %os_name% | findstr "10" >nul
    if !errorlevel! equ 0 (set "os_label=Windows 10 LTSC 2019/2021") else (set "os_label=Windows 11 LTSC 2024")
    goto :found
)

:: 2. 匹配 Server 2025
echo %os_name% | findstr /i "2025" >nul
if !errorlevel! equ 0 (
    echo %os_name% | findstr /i "Datacenter 数据中心" >nul
    if !errorlevel! equ 0 (set "active_key=D764K-2NDRG-47T6Q-P8T8W-YP6DF" & set "os_label=Server 2025 Datacenter") else (set "active_key=TVRH6-WHNXV-R9WG3-9XRFY-MY832" & set "os_label=Server 2025 Standard")
    goto :found
)

:: 3. 匹配普通企业版
echo %os_name% | findstr /i "Enterprise 企业版" >nul
if !errorlevel! equ 0 (
    set "active_key=NPPR9-FWDCX-D2C8J-H872K-2YT43"
    set "os_label=Windows 10/11 Enterprise"
    goto :found
)

:found
if "%active_key%"=="" (
    echo [错误] 无法匹配当前系统版本。
    pause
    exit
)

echo [匹配] 目标版本: %os_label%
echo [匹配] 专用密钥: !active_key!
echo.

set /p kms_ip=请输入 KMS IP (默认 192.168.1.74): 
if "%kms_ip%"=="" set "kms_ip=192.168.1.74"

echo.
echo [执行] 正在安装密钥并激活...
cscript //nologo %systemroot%\system32\slmgr.vbs -upk >nul 2>&1
cscript //nologo %systemroot%\system32\slmgr.vbs -ipk !active_key!
cscript //nologo %systemroot%\system32\slmgr.vbs -skms %kms_ip%
cscript //nologo %systemroot%\system32\slmgr.vbs /ato

echo.
echo ========================================
echo 激活结果摘要:
cscript //nologo %systemroot%\system32\slmgr.vbs -dlv | findstr "已授权 许可证状态"
echo ========================================
pause